home *** CD-ROM | disk | FTP | other *** search
/ The Very Best of Atari Inside / The Very Best of Atari Inside 1.iso / mint / mntlib43 / mntlib / _umulsi3.s < prev    next >
Text File  |  1993-10-20  |  801b  |  36 lines
  1. | unsigned long integer multiplication routine
  2. |
  3. | written by Kai-Uwe Bloem (I5110401@dbstu1.bitnet).
  4. |
  5. |
  6. | Revision 1.1, kub 03-90
  7. | first version, replaces the appropriate routine from fixnum.s.
  8. | This one is short and fast for the common case of both longs <= 0x0000ffff,
  9. | but the case of a zero lowword is no longer recognized.
  10. | (besides it's easier to read this source 8-)
  11.  
  12.     .text
  13.     .even
  14.     .globl    __umulsi3, ___umulsi3, .ulmul
  15.  
  16. .ulmul:
  17. __umulsi3:
  18. ___umulsi3:
  19.     movel    d2,a0        | save registers
  20.     movel    d3,a1
  21.     movemw    sp@(4),d0-d3    | get the two longs. u = d0-d1, v = d2-d3
  22.     extl    d0        | u.h <> 0 ?
  23.     beq    1f
  24.     mulu    d3,d0        | r  = v.l * u.h
  25. 1:    tstw    d2        | v.h <> 0 ?
  26.     beq    2f
  27.     mulu    d1,d2        | r += v.h * u.l
  28.     addw    d2,d0
  29. 2:    swap    d0
  30.     clrw    d0
  31.     mulu    d3,d1        | r += v.l * u.l
  32.     addl    d1,d0
  33.     movel    a1,d3
  34.     movel    a0,d2
  35.     rts
  36.